indir

Aşağıdaki kodu son günlerde herkes istediği için mircscripts.org adresinden ^Andy'nin download için socket örneğini (http://www.mircscripts.org/download.php?id=85) sizler için biraz değiştirdim. Kodu remote'a (ALT+R) koyuyorsunuz.
/download adres istediğiniz-dosya komutuyla çalışıyor, örneğin www.ircforumlari.net/selam.txt dosyasını almak istiyorsak kullanmamız gereken komut:
/download ircforumlari.net selam.txt
İşte kod:

alias download {
if ($sock(download)) {
echo $colour(info text) @download *** başka bir dosya download ediliyor, birazdan tekrar deneyiniz.
return
}
sockopen download $1 80
sockmark download $1 $2
}
on *:sockopen:download:{
if ($sockerr) {
echo $colour(info text) @download *** download ederken hata: $sockerr
return
}
write -c $gettok($sock($sockname).mark,2,32)
unset %downloadlength %downloadready
window -c @download
sockwrite -n $sockname GET $+(/,$gettok($sock($sockname).mark,2,32)) HTTP/1.0
sockwrite -n $sockname Accept: */*
sockwrite -n $sockname Host: $gettok($sock($sockname).mark,1,32)
sockwrite -n $sockname
}
on *:sockread:download:{
if (%downloadready != 1) {
var %header
sockread %header
while ($sockbr) {
if (Content-length: * iswm %header) {
%downloadlength = $gettok(%header,2,32)
if (* !iswm $window(@download)) window @download
echo $colour(info text) @download *** dosya boyutu: %downloadlength bytes
}
elseif (* !iswm %header) {
%downloadready = 1
%downloadoffset = $sock($sockname).rcvd
break
}
sockread %header
}
}
sockread 4096 &d
while ($sockbr) {
if (* !iswm $window(@download)) window @download
echo $colour(info text) @download *** alınan: $round( $calc(100 * ($sock($sockname).rcvd - %downloadoffset) / %downloadlength) ,1) $+ %
bwrite $gettok($sock($sockname).mark,2,32) -1 -1 &d
sockread 4096 &d
}
}
on *:sockclose:download:{
echo $colour(info text) @download *** indirme tamamlandı.
}